nixos-configs/flake.nix

{
  inputs = {
    nixpkgs-2305.url = "github:NixOS/nixpkgs/23.05";
    nixpkgs-2311.url = "github:NixOS/nixpkgs/23.11";
    flake-compat = {
      url = "github:edolstra/flake-compat";
      flake = false;
    };
    nixos-wsl = {
      url = "github:nix-community/NixOS-WSL";
      inputs.nixpkgs.follows = "nixpkgs-2305";
      inputs.flake-compat.follows = "flake-compat";
    };
    intake = {
      url = "git+ssh://gitea@git.alogoulogoi.com/Jaculabilis/intake.git";
      inputs.nixpkgs.follows = "nixpkgs-2305";
      inputs.flake-compat.follows = "flake-compat";
    };
    intake-sources = {
      url = "git+ssh://gitea@git.alogoulogoi.com/Jaculabilis/intake-sources.git";
      inputs.nixpkgs.follows = "nixpkgs-2305";
    };
  };

  outputs = {
    self,
    nixpkgs-2305,
    nixpkgs-2311,
    flake-compat,
    nixos-wsl,
    intake,
    intake-sources,
  }@inputs: {
    nixosModules.beatific = import ./modules/beatific.nix;

    nixosConfigurations = let
      pinNixpkgs = nixpkgs: { ... }: {
        nix.registry.nixpkgs.to = { type = "path"; path = nixpkgs; };
      };
    in {
      backyard = nixpkgs-2311.lib.nixosSystem {
        system = "x86_64-linux";
        modules = [
          self.nixosModules.beatific
          (pinNixpkgs nixpkgs-2311)
          ./machine/backyard
        ];
      };
      catacomb = nixpkgs-2305.lib.nixosSystem {
        system = "aarch64-linux";
        modules = [
          self.nixosModules.beatific
          (pinNixpkgs nixpkgs-2305)
          ./machine/catacomb
        ];
      };
      empyrean = nixpkgs-2305.lib.nixosSystem {
        system = "x86_64-linux";
        modules = [
          self.nixosModules.beatific
          intake.nixosModules.default
          intake-sources.nixosModules.default
          (pinNixpkgs nixpkgs-2305)
          ./machine/empyrean
        ];
      };
      imperium = nixpkgs-2311.lib.nixosSystem {
        system = "x86_64-linux";
        modules = [
          self.nixosModules.beatific
          (pinNixpkgs nixpkgs-2311)
          ({ ... }: {
            environment.systemPackages = [ nixpkgs-2311.legacyPackages."i686-linux".gperftools ];
          })
          ./machine/imperium
        ];
      };
      stagirite = nixpkgs-2305.lib.nixosSystem {
        system = "x86_64-linux";
        modules = [
          nixos-wsl.nixosModules.wsl
          ./machine/stagirite
        ];
      };
      unfolder = nixpkgs-2305.lib.nixosSystem {
        system = "x86_64-linux";
        modules = [
          self.nixosModules.beatific
          (pinNixpkgs nixpkgs-2305)
          ./machine/unfolder
        ];
      };
    };
  };
}