nixos-configs/flake.nix

{
  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/22.11";
    nixpkgs-next.url = "github:NixOS/nixpkgs/23.05";
    flake-compat = {
      url = "github:edolstra/flake-compat";
      flake = false;
    };
    nixos-wsl = {
      url = "github:nix-community/NixOS-WSL";
      inputs.nixpkgs.follows = "nixpkgs";
      inputs.flake-compat.follows = "flake-compat";
    };
    intake = {
      url = "git+ssh://gitea@git.alogoulogoi.com/Jaculabilis/intake.git";
      inputs.nixpkgs.follows = "nixpkgs-next";
      inputs.flake-compat.follows = "flake-compat";
    };
    intake-sources = {
      url = "git+ssh://gitea@git.alogoulogoi.com/Jaculabilis/intake-sources.git";
      inputs.nixpkgs.follows = "nixpkgs-next";
    };
  };

  outputs = {
    self,
    nixpkgs,
    nixpkgs-next,
    flake-compat,
    nixos-wsl,
    intake,
    intake-sources,
  }: {
    nixosModules.beatific = import ./modules/beatific.nix;

    nixosConfigurations = {
      backyard = nixpkgs-next.lib.nixosSystem {
        system = "x86_64-linux";
        modules = [
          self.nixosModules.beatific
          ./machine/backyard
        ];
      };
      catacomb = nixpkgs.lib.nixosSystem {
        system = "aarch64-linux";
        modules = [ ./machine/catacomb ];
      };
      empyrean = nixpkgs-next.lib.nixosSystem {
        system = "x86_64-linux";
        modules = [
          intake.nixosModules.default
          intake-sources.nixosModules.default
          ./machine/empyrean
        ];
      };
      stagirite = nixpkgs.lib.nixosSystem {
        system = "x86_64-linux";
        modules = [
          nixos-wsl.nixosModules.wsl
          ./machine/stagirite
        ];
      };
    };
  };
}