www/flake.nix

{
  inputs.nixpkgs.url = "github:NixOS/nixpkgs/23.05";

  outputs = { self, nixpkgs }: let
    system = "x86_64-linux";
    patched = (import nixpkgs { inherit system; }).applyPatches {
      name = "nixpkgs+247773";
      src = nixpkgs;
      patches = [
        ./patches/b6910512a0789390af9db312ee8f08665bd662ab.patch
        ./patches/f23952856444fe39fad622a0db9eae55cd0f6fe8.patch
        ./patches/095afd88c41f08cb37e9cd67429baaa8d02e2d6f.patch
      ];
    };
    pkgs = import patched { inherit system; };
    #pkgs = nixpkgs.legacyPackages.${system};
    pyenv = pkgs.python3.withPackages (pypkgs: [
      pypkgs.markdown
      pypkgs.beautifulsoup4
      pypkgs.feedgen
    ]);
  in {
    packages.${system} = {
      inherit pyenv;
    };

    devShells.${system} = {
      default = pkgs.mkShell {
        packages = [
          pyenv
          pkgs.inotify-tools
          pkgs.rsync
          pkgs.pagefind
        ];
        shellHook = ''
          echo "make build - compile src/ into out/ with pagefind"
          echo "make clean - delete out/ and srv/"
          echo "make watch - rebuild on changes"
          echo "make serve - serve out/"
          echo "make pubdate - replace 'now' with the current date"
          echo "make upload - build to srv/ and upload to alogoulogoi"
        '';
      };
    };
  };
}