{
  description = "Universal and extensible feed aggregator";

  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixos-unstable";
    nixos-shell.url = "github:Mic92/nixos-shell";
    nixos-shell.inputs.nixpkgs.follows = "nixpkgs";
  };

  outputs =
    {
      self,
      nixpkgs,
      nixos-shell,
    }:
    let
      inherit (nixpkgs.lib) nixosSystem;
      system = "x86_64-linux";
      pkgs = nixpkgs.legacyPackages.${system};
    in
    {
      formatter = nixpkgs.legacyPackages.${system}.nixfmt-rfc-style;

      packages.${system} =
        let
          pkgs = (
            import nixpkgs {
              inherit system;
              overlays = [ self.overlays.default ];
            }
          );
        in 
        {
          default = self.packages.${system}.intake;
          inherit (pkgs) intake;
        };

      devShells.${system}.default = pkgs.mkShell {
        packages = [
          pkgs.go
          pkgs.gopls
          pkgs.go-tools
          pkgs.gotools
          pkgs.cobra-cli
          pkgs.air
          pkgs.nixos-shell
        ];
      };

      overlays.default = final: prev: {
        intake = final.callPackage ./package.nix { };
      };
    
      nixosModules.default = import ./module.nix self;

      nixosConfigurations."demo" = nixosSystem {
        inherit system;
        modules = [
          nixos-shell.nixosModules.nixos-shell
          self.nixosModules.default
          ./demo
        ];
      };
    };
}